mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Ken TominagaandFacebook GitHub Bot
c73e021a4b
Summary: We don't have to check or emulate the safe area for iOS 11 above. I deleted the unnecessary check for the safe area. This is a continuation pull request of these iOS 11 availability check. * [Remove iOS 11 version check by ken0nek · Pull Request https://github.com/facebook/react-native/issues/32151 · facebook/react-native](https://github.com/facebook/react-native/pull/32151) * [Remove iOS 11 availability check by ken0nek · Pull Request https://github.com/facebook/react-native/issues/32488 · facebook/react-native](https://github.com/facebook/react-native/pull/32488) ----- - Stop using layout guide (`topLayoutGuide`, `bottomLayoutGuide`) - Refactor `RCTSafeAreaView` - Delete `emulateUnlessSupported` property Docs PR: https://github.com/facebook/react-native-website/pull/2919 ## Changelog <!-- Help reviewers and the release process by writing your own changelog entry. For an example, see: https://github.com/facebook/react-native/wiki/Changelog --> [iOS] [Removed] - Remove `emulateUnlessSupported` Pull Request resolved: https://github.com/facebook/react-native/pull/32851 Reviewed By: philIip, sammy-SC Differential Revision: D33586023 Pulled By: cortinico fbshipit-source-id: 75fc1037141f71d9340c7b875a6bf86f9cfd6a02
103 lines
2.8 KiB
Plaintext
103 lines
2.8 KiB
Plaintext
/*
|
|
* Copyright (c) Meta Platforms, Inc. and affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTSafeAreaViewComponentView.h"
|
|
|
|
#import <React/RCTUtils.h>
|
|
#import <react/renderer/components/safeareaview/SafeAreaViewComponentDescriptor.h>
|
|
#import <react/renderer/components/safeareaview/SafeAreaViewState.h>
|
|
#import "RCTConversions.h"
|
|
#import "RCTFabricComponentsPlugins.h"
|
|
|
|
using namespace facebook::react;
|
|
|
|
@implementation RCTSafeAreaViewComponentView {
|
|
SafeAreaViewShadowNode::ConcreteState::Shared _state;
|
|
}
|
|
|
|
- (instancetype)initWithFrame:(CGRect)frame
|
|
{
|
|
if (self = [super initWithFrame:frame]) {
|
|
static auto const defaultProps = std::make_shared<SafeAreaViewProps const>();
|
|
_props = defaultProps;
|
|
self.clipsToBounds = YES;
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
- (void)safeAreaInsetsDidChange
|
|
{
|
|
[super safeAreaInsetsDidChange];
|
|
|
|
[self _updateStateIfNecessary];
|
|
}
|
|
|
|
- (void)_updateStateIfNecessary
|
|
{
|
|
if (!_state) {
|
|
return;
|
|
}
|
|
|
|
UIEdgeInsets insets = self.safeAreaInsets;
|
|
insets.left = RCTRoundPixelValue(insets.left);
|
|
insets.top = RCTRoundPixelValue(insets.top);
|
|
insets.right = RCTRoundPixelValue(insets.right);
|
|
insets.bottom = RCTRoundPixelValue(insets.bottom);
|
|
|
|
auto newPadding = RCTEdgeInsetsFromUIEdgeInsets(insets);
|
|
auto threshold = 1.0 / RCTScreenScale() + 0.01; // Size of a pixel plus some small threshold.
|
|
|
|
_state->updateState(
|
|
[=](SafeAreaViewShadowNode::ConcreteState::Data const &oldData)
|
|
-> SafeAreaViewShadowNode::ConcreteState::SharedData {
|
|
auto oldPadding = oldData.padding;
|
|
auto deltaPadding = newPadding - oldPadding;
|
|
|
|
if (std::abs(deltaPadding.left) < threshold && std::abs(deltaPadding.top) < threshold &&
|
|
std::abs(deltaPadding.right) < threshold && std::abs(deltaPadding.bottom) < threshold) {
|
|
return nullptr;
|
|
}
|
|
|
|
auto newData = oldData;
|
|
newData.padding = newPadding;
|
|
return std::make_shared<SafeAreaViewShadowNode::ConcreteState::Data const>(newData);
|
|
});
|
|
}
|
|
|
|
#pragma mark - RCTComponentViewProtocol
|
|
|
|
+ (ComponentDescriptorProvider)componentDescriptorProvider
|
|
{
|
|
return concreteComponentDescriptorProvider<SafeAreaViewComponentDescriptor>();
|
|
}
|
|
|
|
- (void)updateState:(facebook::react::State::Shared const &)state
|
|
oldState:(facebook::react::State::Shared const &)oldState
|
|
{
|
|
_state = std::static_pointer_cast<SafeAreaViewShadowNode::ConcreteState const>(state);
|
|
}
|
|
|
|
- (void)finalizeUpdates:(RNComponentViewUpdateMask)updateMask
|
|
{
|
|
[super finalizeUpdates:updateMask];
|
|
[self _updateStateIfNecessary];
|
|
}
|
|
|
|
- (void)prepareForRecycle
|
|
{
|
|
[super prepareForRecycle];
|
|
_state.reset();
|
|
}
|
|
|
|
@end
|
|
|
|
Class<RCTComponentViewProtocol> RCTSafeAreaViewCls(void)
|
|
{
|
|
return RCTSafeAreaViewComponentView.class;
|
|
}
|