mirror of
https://github.com/simplex-chat/haskell.nix.git
synced 2026-06-03 09:17:32 +00:00
Hamish Mackenzie
9e3463d65f
* Switch to enableNativeBignum = true when available * Fix bitvec dependency on gmp Adds https://github.com/Bodigrim/bitvec/pull/61 * Fix dynamic linking tests (now GMP is not always linked) Co-authored-by: Tom McLaughlin <tom@codedown.io>
62 lines
1.8 KiB
Nix
62 lines
1.8 KiB
Nix
# Test a package set
|
|
{ stdenv, lib, util, cabalProject', haskellLib, recurseIntoAttrs, testSrc, compiler-nix-name, evalPackages }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
project = cabalProject' {
|
|
inherit compiler-nix-name evalPackages;
|
|
src = testSrc "sublib-docs";
|
|
cabalProject = ''
|
|
packages: .
|
|
allow-newer: aeson:*
|
|
'';
|
|
};
|
|
|
|
packages = project.hsPkgs;
|
|
|
|
in recurseIntoAttrs {
|
|
# Haddock is not included with cross compilers currently
|
|
meta.disabled = haskellLib.isCrossHost;
|
|
ifdInputs = {
|
|
inherit (project) plan-nix;
|
|
};
|
|
run = stdenv.mkDerivation {
|
|
name = "sublib-docs-test";
|
|
|
|
buildCommand = ''
|
|
exe="${packages.sublib-docs.components.exes.sublib-docs.exePath}"
|
|
|
|
size=$(command stat --format '%s' "$exe")
|
|
printf "size of executable $exe is $size. \n" >& 2
|
|
|
|
# fixme: run on target platform when cross-compiled
|
|
printf "checking whether executable runs... " >& 2
|
|
cat ${haskellLib.check packages.sublib-docs.components.exes.sublib-docs}/test-stdout
|
|
|
|
'' +
|
|
# Musl and Aarch are statically linked..
|
|
optionalString (!stdenv.hostPlatform.isAarch32 && !stdenv.hostPlatform.isAarch64 && !stdenv.hostPlatform.isMusl) (''
|
|
printf "checking that executable is dynamically linked to system libraries... " >& 2
|
|
'' + optionalString (stdenv.isLinux && !stdenv.hostPlatform.isMusl) ''
|
|
ldd $exe | grep 'libc[.]so'
|
|
'' + optionalString stdenv.isDarwin ''
|
|
otool -L $exe |grep .dylib
|
|
'') + ''
|
|
|
|
# Check that it looks like we have docs
|
|
test -f "${packages.sublib-docs.components.library.doc}/share/doc/sublib-docs/html/Lib.html"
|
|
test -f "${packages.sublib-docs.components.sublibs.slib.doc}/share/doc/slib/html/Slib.html"
|
|
|
|
touch $out
|
|
'';
|
|
|
|
meta.platforms = platforms.all;
|
|
|
|
passthru = {
|
|
# Used for debugging with nix repl
|
|
inherit packages;
|
|
};
|
|
};
|
|
}
|