mirror of
https://github.com/apple/swift-argument-parser.git
synced 2026-06-06 20:18:23 +00:00
Fabrice de Gans
27e280f69e
* [cmake] Install libraries in standard directories
Previously, libraries were installed under `lib/swift/${os}/`. They
should be installed in the default library directory for the relevant
target system.
In addition, swiftmodules were installed in the older layout format on
non-Darwin platforms. This changes to use the standard modern layout
format for swiftmodules.
* Use full triple for swiftmodule filenames
* Extract Swift_MODULE_TRIPLE from the function
* Fail early in case the triple cannot be found
* Enable C language before using GNUInstallDirs
* Add C language in project definition
Enabling the C language after Swift was causing issues with using the C
compiler.
113 lines
4.2 KiB
CMake
113 lines
4.2 KiB
CMake
# Returns the architecture name in a variable
|
|
#
|
|
# Usage:
|
|
# get_swift_host_arch(result_var_name)
|
|
#
|
|
# Sets ${result_var_name} with the converted architecture name derived from
|
|
# CMAKE_SYSTEM_PROCESSOR.
|
|
function(get_swift_host_arch result_var_name)
|
|
if("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64")
|
|
set("${result_var_name}" "x86_64" PARENT_SCOPE)
|
|
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64|ARM64|arm64")
|
|
if(NOT DEFINED CMAKE_OSX_DEPLOYMENT_TARGET OR
|
|
"${CMAKE_OSX_DEPLOYMENT_TARGET}" STREQUAL "")
|
|
set("${result_var_name}" "aarch64" PARENT_SCOPE)
|
|
else()
|
|
set("${result_var_name}" "arm64" PARENT_SCOPE)
|
|
endif()
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "ppc64")
|
|
set("${result_var_name}" "powerpc64" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "ppc64le")
|
|
set("${result_var_name}" "powerpc64le" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "s390x")
|
|
set("${result_var_name}" "s390x" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "armv6l")
|
|
set("${result_var_name}" "armv6" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "armv7-a")
|
|
set("${result_var_name}" "armv7" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "armv7l")
|
|
set("${result_var_name}" "armv7" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "amd64")
|
|
set("${result_var_name}" "amd64" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "AMD64")
|
|
set("${result_var_name}" "x86_64" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "IA64")
|
|
set("${result_var_name}" "itanium" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86")
|
|
set("${result_var_name}" "i686" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "i686")
|
|
set("${result_var_name}" "i686" PARENT_SCOPE)
|
|
elseif("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "riscv64")
|
|
set("${result_var_name}" "riscv64" PARENT_SCOPE)
|
|
else()
|
|
message(FATAL_ERROR "Unrecognized architecture on host system: ${CMAKE_SYSTEM_PROCESSOR}")
|
|
endif()
|
|
endfunction()
|
|
|
|
# Returns the os name in a variable
|
|
#
|
|
# Usage:
|
|
# get_swift_host_os(result_var_name)
|
|
#
|
|
#
|
|
# Sets ${result_var_name} with the converted OS name derived from
|
|
# CMAKE_SYSTEM_NAME.
|
|
function(get_swift_host_os result_var_name)
|
|
if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
|
|
set(${result_var_name} macosx PARENT_SCOPE)
|
|
else()
|
|
string(TOLOWER ${CMAKE_SYSTEM_NAME} cmake_system_name_lc)
|
|
set(${result_var_name} ${cmake_system_name_lc} PARENT_SCOPE)
|
|
endif()
|
|
endfunction()
|
|
|
|
if(NOT Swift_MODULE_TRIPLE)
|
|
# Attempt to get the module triple from the Swift compiler.
|
|
set(module_triple_command "${CMAKE_Swift_COMPILER}" -print-target-info)
|
|
if(CMAKE_Swift_COMPILER_TARGET)
|
|
list(APPEND module_triple_command -target ${CMAKE_Swift_COMPILER_TARGET})
|
|
endif()
|
|
execute_process(COMMAND ${module_triple_command}
|
|
OUTPUT_VARIABLE target_info_json)
|
|
string(JSON module_triple GET "${target_info_json}" "target" "moduleTriple")
|
|
|
|
# Exit now if we failed to infer the triple.
|
|
if(NOT module_triple)
|
|
message(FATAL_ERROR
|
|
"Failed to get module triple from Swift compiler. "
|
|
"Compiler output: ${target_info_json}")
|
|
endif()
|
|
|
|
# Cache the module triple for future use.
|
|
set(Swift_MODULE_TRIPLE "${module_triple}" CACHE STRING "swift module triple used for installed swiftmodule and swiftinterface files")
|
|
mark_as_advanced(Swift_MODULE_TRIPLE)
|
|
endif()
|
|
|
|
function(_install_target module)
|
|
get_swift_host_os(swift_os)
|
|
get_target_property(type ${module} TYPE)
|
|
|
|
if(type STREQUAL STATIC_LIBRARY)
|
|
set(swift swift_static)
|
|
else()
|
|
set(swift swift)
|
|
endif()
|
|
|
|
install(TARGETS ${module})
|
|
if(type STREQUAL EXECUTABLE)
|
|
return()
|
|
endif()
|
|
|
|
get_target_property(module_name ${module} Swift_MODULE_NAME)
|
|
if(NOT module_name)
|
|
set(module_name ${module})
|
|
endif()
|
|
|
|
install(FILES $<TARGET_PROPERTY:${module},Swift_MODULE_DIRECTORY>/${module_name}.swiftdoc
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/${swift}/${swift_os}/${module_name}.swiftmodule
|
|
RENAME ${Swift_MODULE_TRIPLE}.swiftdoc)
|
|
install(FILES $<TARGET_PROPERTY:${module},Swift_MODULE_DIRECTORY>/${module_name}.swiftmodule
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/${swift}/${swift_os}/${module_name}.swiftmodule
|
|
RENAME ${Swift_MODULE_TRIPLE}.swiftmodule)
|
|
endfunction()
|