mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Ramanpreet Nara
652fa1b8d4
Summary:
## Purpose
We must modify the `getTurboModuleWithJsInvoker:` method of all our NativeModules to also accept a `id<RCTTurboModulePerformanceLogger>` object. This performance logger object should then be forwarded to the `Native*SpecJSI` constructor.
## Script
Run the following script via Node:
```
var withSpaces = (...args) => args.join('\s*')
var regexString = withSpaces(
'-',
'\(',
'std::shared_ptr',
'<',
'(?<turboModuleClass>(facebook::react::|react::|::|)TurboModule)',
'>',
'\)',
'getTurboModuleWithJsInvoker',
':',
'\(',
'std::shared_ptr',
'<',
'(?<callInvokerClass>(facebook::react::|react::|::|)CallInvoker)',
'>',
'\)',
'jsInvoker',
'{',
'return',
'std::make_shared',
'<',
'(?<specName>(facebook::react::|react::|::|)Native[A-Za-z0-9]+SpecJSI)',
'>',
'\(',
'(?<arg1>[A-Za-z0-9]+)',
',',
'(?<arg2>[A-Za-z0-9]+)',
'\)',
';',
'}',
)
var replaceString = `- (std::shared_ptr<$<turboModuleClass>>)
getTurboModuleWithJsInvoker:(std::shared_ptr<$<callInvokerClass>>)jsInvoker
perfLogger:(id<RCTTurboModulePerformanceLogger>)perfLogger
{
return std::make_shared<$<specName>>($<arg1>, $<arg2>, perfLogger);
}`
const exec = (cmd) => require('child_process').execSync(cmd, { encoding: 'utf8' });
const abspath = (filename) => `${process.env.HOME}/${filename}`;
const relpath = (filename) => filename.replace(process.env.HOME + '/', '');
const readFile = (filename) => require('fs').readFileSync(filename, 'utf8');
const writeFile = (filename, content) => require('fs').writeFileSync(filename, content);
function main() {
const tmFiles = exec('cd ~/fbsource && xbgs -n 10000 -l getTurboModuleWithJsInvoker:').split('\n').filter(Boolean);
tmFiles
.filter((filename) => !filename.includes('microsoft-fork-of-react-native'))
.map(abspath)
.forEach((filename) => {
const source = readFile(filename);
const newSource = source.replace(new RegExp(regexString, 'g'), replaceString);
if (source == newSource) {
console.log(relpath(filename));
}
writeFile(filename, newSource);
});
}
if (!module.parent) {
main();
}
```
Also, run: `pushd ~/fbsource && js1 build oss-native-modules-specs -p ios && js1 build oss-native-modules-specs -p android && popd;`
Changelog: [Internal]
Reviewed By: fkgozali
Differential Revision: D20478718
fbshipit-source-id: 89ee27ed8a0338a66a9b2dbb716168a4c4582c44
164 lines
5.4 KiB
Plaintext
164 lines
5.4 KiB
Plaintext
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTExceptionsManager.h"
|
|
|
|
#import <FBReactNativeSpec/FBReactNativeSpec.h>
|
|
#import <React/RCTConvert.h>
|
|
#import <React/RCTDefines.h>
|
|
#import <React/RCTLog.h>
|
|
#import <React/RCTRedBox.h>
|
|
#import <React/RCTReloadCommand.h>
|
|
#import <React/RCTRootView.h>
|
|
|
|
#import "CoreModulesPlugins.h"
|
|
|
|
@interface RCTExceptionsManager () <NativeExceptionsManagerSpec>
|
|
|
|
@end
|
|
|
|
@implementation RCTExceptionsManager
|
|
|
|
@synthesize bridge = _bridge;
|
|
|
|
RCT_EXPORT_MODULE()
|
|
|
|
- (instancetype)initWithDelegate:(id<RCTExceptionsManagerDelegate>)delegate
|
|
{
|
|
if ((self = [self init])) {
|
|
_delegate = delegate;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (void)reportSoft:(NSString *)message
|
|
stack:(NSArray<NSDictionary *> *)stack
|
|
exceptionId:(double)exceptionId
|
|
suppressRedBox:(BOOL)suppressRedBox
|
|
{
|
|
if (!suppressRedBox) {
|
|
[_bridge.redBox showErrorMessage:message withStack:stack errorCookie:((int)exceptionId)];
|
|
}
|
|
|
|
if (_delegate) {
|
|
[_delegate handleSoftJSExceptionWithMessage:message
|
|
stack:stack
|
|
exceptionId:[NSNumber numberWithDouble:exceptionId]];
|
|
}
|
|
}
|
|
|
|
- (void)reportFatal:(NSString *)message
|
|
stack:(NSArray<NSDictionary *> *)stack
|
|
exceptionId:(double)exceptionId
|
|
suppressRedBox:(BOOL)suppressRedBox
|
|
{
|
|
if (!suppressRedBox) {
|
|
[_bridge.redBox showErrorMessage:message withStack:stack errorCookie:((int)exceptionId)];
|
|
}
|
|
|
|
if (_delegate) {
|
|
[_delegate handleFatalJSExceptionWithMessage:message
|
|
stack:stack
|
|
exceptionId:[NSNumber numberWithDouble:exceptionId]];
|
|
}
|
|
|
|
static NSUInteger reloadRetries = 0;
|
|
if (!RCT_DEBUG && reloadRetries < _maxReloadAttempts) {
|
|
reloadRetries++;
|
|
RCTTriggerReloadCommandListeners(@"JS Crash Reload");
|
|
} else if (!RCT_DEV || !suppressRedBox) {
|
|
NSString *description = [@"Unhandled JS Exception: " stringByAppendingString:message];
|
|
NSDictionary *errorInfo = @{NSLocalizedDescriptionKey : description, RCTJSStackTraceKey : stack};
|
|
RCTFatal([NSError errorWithDomain:RCTErrorDomain code:0 userInfo:errorInfo]);
|
|
}
|
|
}
|
|
|
|
RCT_EXPORT_METHOD(reportSoftException
|
|
: (NSString *)message stack
|
|
: (NSArray<NSDictionary *> *)stack exceptionId
|
|
: (double)exceptionId)
|
|
{
|
|
[self reportSoft:message stack:stack exceptionId:exceptionId suppressRedBox:NO];
|
|
}
|
|
|
|
RCT_EXPORT_METHOD(reportFatalException
|
|
: (NSString *)message stack
|
|
: (NSArray<NSDictionary *> *)stack exceptionId
|
|
: (double)exceptionId)
|
|
{
|
|
[self reportFatal:message stack:stack exceptionId:exceptionId suppressRedBox:NO];
|
|
}
|
|
|
|
RCT_EXPORT_METHOD(updateExceptionMessage
|
|
: (NSString *)message stack
|
|
: (NSArray<NSDictionary *> *)stack exceptionId
|
|
: (double)exceptionId)
|
|
{
|
|
[_bridge.redBox updateErrorMessage:message withStack:stack errorCookie:((int)exceptionId)];
|
|
|
|
if (_delegate && [_delegate respondsToSelector:@selector(updateJSExceptionWithMessage:stack:exceptionId:)]) {
|
|
[_delegate updateJSExceptionWithMessage:message stack:stack exceptionId:[NSNumber numberWithDouble:exceptionId]];
|
|
}
|
|
}
|
|
|
|
// Deprecated. Use reportFatalException directly instead.
|
|
RCT_EXPORT_METHOD(reportUnhandledException : (NSString *)message stack : (NSArray<NSDictionary *> *)stack)
|
|
{
|
|
[self reportFatalException:message stack:stack exceptionId:-1];
|
|
}
|
|
|
|
RCT_EXPORT_METHOD(dismissRedbox) {}
|
|
|
|
RCT_EXPORT_METHOD(reportException : (JS::NativeExceptionsManager::ExceptionData &)data)
|
|
{
|
|
NSString *message = data.message();
|
|
double exceptionId = data.id_();
|
|
id<NSObject> extraData = data.extraData();
|
|
|
|
// Reserialize data.stack() into an array of untyped dictionaries.
|
|
// TODO: (moti) T53588496 Replace `(NSArray<NSDictionary *> *)stack` in
|
|
// reportFatalException etc with a typed interface.
|
|
NSMutableArray<NSDictionary *> *stackArray = [NSMutableArray<NSDictionary *> new];
|
|
for (auto frame : data.stack()) {
|
|
NSMutableDictionary *frameDict = [NSMutableDictionary new];
|
|
if (frame.column().hasValue()) {
|
|
frameDict[@"column"] = @(frame.column().value());
|
|
}
|
|
frameDict[@"file"] = frame.file();
|
|
if (frame.lineNumber().hasValue()) {
|
|
frameDict[@"lineNumber"] = @(frame.lineNumber().value());
|
|
}
|
|
frameDict[@"methodName"] = frame.methodName();
|
|
if (frame.collapse().hasValue()) {
|
|
frameDict[@"collapse"] = @(frame.collapse().value());
|
|
}
|
|
[stackArray addObject:frameDict];
|
|
}
|
|
NSDictionary *dict = (NSDictionary *)extraData;
|
|
BOOL suppressRedBox = [[dict objectForKey:@"suppressRedBox"] boolValue];
|
|
|
|
if (data.isFatal()) {
|
|
[self reportFatal:message stack:stackArray exceptionId:exceptionId suppressRedBox:suppressRedBox];
|
|
} else {
|
|
[self reportSoft:message stack:stackArray exceptionId:exceptionId suppressRedBox:suppressRedBox];
|
|
}
|
|
}
|
|
|
|
- (std::shared_ptr<facebook::react::TurboModule>)
|
|
getTurboModuleWithJsInvoker:(std::shared_ptr<facebook::react::CallInvoker>)jsInvoker
|
|
perfLogger:(id<RCTTurboModulePerformanceLogger>)perfLogger
|
|
{
|
|
return std::make_shared<facebook::react::NativeExceptionsManagerSpecJSI>(self, jsInvoker, perfLogger);
|
|
}
|
|
|
|
@end
|
|
|
|
Class RCTExceptionsManagerCls(void)
|
|
{
|
|
return RCTExceptionsManager.class;
|
|
}
|