mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Valentin Shergin
b5cd9e4db1
Summary: In some cases, the view class is the only that retains stored `props_` variable. At the same time the `[super updateProps:props oldProps:oldProps];` actually resets the pointer with a pointer to new props value which sometimes causes the deallocation of the old value. All that is okay unless the implementation of `updateProps:oldProps:` in superclasses stores a raw reference to an old value in the very beginning of the method (for convenience and perf reasons). So, to prevent preliminary deallocation of the old value pointed by `_props` we moved all `[super updateProps:props oldProps:oldProps];` calls to the end of overloaded methods. Reviewed By: mdvacca Differential Revision: D15770068 fbshipit-source-id: af36b3e70560ab00846cd26b0963bbc059e977bc
92 lines
2.5 KiB
Plaintext
92 lines
2.5 KiB
Plaintext
/**
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTSwitchComponentView.h"
|
|
|
|
#import <react/components/rncore/ComponentDescriptors.h>
|
|
#import <react/components/rncore/EventEmitters.h>
|
|
#import <react/components/rncore/Props.h>
|
|
|
|
using namespace facebook::react;
|
|
|
|
@implementation RCTSwitchComponentView {
|
|
UISwitch *_switchView;
|
|
BOOL _wasOn;
|
|
}
|
|
|
|
- (instancetype)initWithFrame:(CGRect)frame
|
|
{
|
|
if (self = [super initWithFrame:frame]) {
|
|
static const auto defaultProps = std::make_shared<const SwitchProps>();
|
|
_props = defaultProps;
|
|
|
|
_switchView = [[UISwitch alloc] initWithFrame:self.bounds];
|
|
|
|
[_switchView addTarget:self action:@selector(onChange:) forControlEvents:UIControlEventValueChanged];
|
|
|
|
_switchView.on = defaultProps->value;
|
|
|
|
self.contentView = _switchView;
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
#pragma mark - RCTComponentViewProtocol
|
|
|
|
+ (ComponentDescriptorProvider)componentDescriptorProvider
|
|
{
|
|
return concreteComponentDescriptorProvider<SwitchComponentDescriptor>();
|
|
}
|
|
|
|
- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps
|
|
{
|
|
const auto &oldSwitchProps = *std::static_pointer_cast<const SwitchProps>(_props);
|
|
const auto &newSwitchProps = *std::static_pointer_cast<const SwitchProps>(props);
|
|
|
|
// `value`
|
|
if (oldSwitchProps.value != newSwitchProps.value) {
|
|
_switchView.on = newSwitchProps.value;
|
|
_wasOn = newSwitchProps.value;
|
|
}
|
|
|
|
// `disabled`
|
|
if (oldSwitchProps.disabled != newSwitchProps.disabled) {
|
|
_switchView.enabled = !newSwitchProps.disabled;
|
|
}
|
|
|
|
// `tintColor`
|
|
if (oldSwitchProps.tintColor != newSwitchProps.tintColor) {
|
|
_switchView.tintColor = [UIColor colorWithCGColor:newSwitchProps.tintColor.get()];
|
|
}
|
|
|
|
// `onTintColor
|
|
if (oldSwitchProps.onTintColor != newSwitchProps.onTintColor) {
|
|
_switchView.onTintColor = [UIColor colorWithCGColor:newSwitchProps.onTintColor.get()];
|
|
}
|
|
|
|
// `thumbTintColor`
|
|
if (oldSwitchProps.thumbTintColor != newSwitchProps.thumbTintColor) {
|
|
_switchView.thumbTintColor = [UIColor colorWithCGColor:newSwitchProps.thumbTintColor.get()];
|
|
}
|
|
|
|
[super updateProps:props oldProps:oldProps];
|
|
}
|
|
|
|
- (void)onChange:(UISwitch *)sender
|
|
{
|
|
if (_wasOn == sender.on) {
|
|
return;
|
|
}
|
|
_wasOn = sender.on;
|
|
|
|
std::dynamic_pointer_cast<const SwitchEventEmitter>(_eventEmitter)
|
|
->onChange(SwitchOnChangeStruct{.value = static_cast<bool>(sender.on)});
|
|
}
|
|
|
|
@end
|