mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Valentin Shergin
b5cd9e4db1
Summary: In some cases, the view class is the only that retains stored `props_` variable. At the same time the `[super updateProps:props oldProps:oldProps];` actually resets the pointer with a pointer to new props value which sometimes causes the deallocation of the old value. All that is okay unless the implementation of `updateProps:oldProps:` in superclasses stores a raw reference to an old value in the very beginning of the method (for convenience and perf reasons). So, to prevent preliminary deallocation of the old value pointed by `_props` we moved all `[super updateProps:props oldProps:oldProps];` calls to the end of overloaded methods. Reviewed By: mdvacca Differential Revision: D15770068 fbshipit-source-id: af36b3e70560ab00846cd26b0963bbc059e977bc
91 lines
3.0 KiB
Plaintext
91 lines
3.0 KiB
Plaintext
/**
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTActivityIndicatorViewComponentView.h"
|
|
|
|
#import <react/components/rncore/ComponentDescriptors.h>
|
|
#import <react/components/rncore/EventEmitters.h>
|
|
#import <react/components/rncore/Props.h>
|
|
|
|
using namespace facebook::react;
|
|
|
|
static UIActivityIndicatorViewStyle convertActivityIndicatorViewStyle(const ActivityIndicatorViewSize &size)
|
|
{
|
|
switch (size) {
|
|
case ActivityIndicatorViewSize::Small:
|
|
return UIActivityIndicatorViewStyleWhite;
|
|
case ActivityIndicatorViewSize::Large:
|
|
return UIActivityIndicatorViewStyleWhiteLarge;
|
|
}
|
|
}
|
|
|
|
@implementation RCTActivityIndicatorViewComponentView {
|
|
UIActivityIndicatorView *_activityIndicatorView;
|
|
}
|
|
|
|
#pragma mark - RCTComponentViewProtocol
|
|
|
|
+ (ComponentDescriptorProvider)componentDescriptorProvider
|
|
{
|
|
return concreteComponentDescriptorProvider<ActivityIndicatorViewComponentDescriptor>();
|
|
}
|
|
|
|
- (instancetype)initWithFrame:(CGRect)frame
|
|
{
|
|
if (self = [super initWithFrame:frame]) {
|
|
static const auto defaultProps = std::make_shared<const ActivityIndicatorViewProps>();
|
|
_props = defaultProps;
|
|
|
|
_activityIndicatorView = [[UIActivityIndicatorView alloc] initWithFrame:self.bounds];
|
|
_activityIndicatorView.autoresizingMask = UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
|
|
|
|
if (defaultProps->animating) {
|
|
[_activityIndicatorView startAnimating];
|
|
} else {
|
|
[_activityIndicatorView stopAnimating];
|
|
}
|
|
_activityIndicatorView.color = [UIColor colorWithCGColor:defaultProps->color.get()];
|
|
_activityIndicatorView.hidesWhenStopped = defaultProps->hidesWhenStopped;
|
|
_activityIndicatorView.activityIndicatorViewStyle = convertActivityIndicatorViewStyle(defaultProps->size);
|
|
|
|
[self addSubview:_activityIndicatorView];
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
- (void)updateProps:(Props::Shared const &)props oldProps:(Props::Shared const &)oldProps
|
|
{
|
|
const auto &oldViewProps = *std::static_pointer_cast<const ActivityIndicatorViewProps>(_props);
|
|
const auto &newViewProps = *std::static_pointer_cast<const ActivityIndicatorViewProps>(props);
|
|
|
|
if (oldViewProps.animating != newViewProps.animating) {
|
|
if (newViewProps.animating) {
|
|
[_activityIndicatorView startAnimating];
|
|
} else {
|
|
[_activityIndicatorView stopAnimating];
|
|
}
|
|
}
|
|
|
|
if (oldViewProps.color.get() != newViewProps.color.get()) {
|
|
_activityIndicatorView.color = [UIColor colorWithCGColor:newViewProps.color.get()];
|
|
}
|
|
|
|
// TODO: This prop should be deprecated.
|
|
if (oldViewProps.hidesWhenStopped != newViewProps.hidesWhenStopped) {
|
|
_activityIndicatorView.hidesWhenStopped = newViewProps.hidesWhenStopped;
|
|
}
|
|
|
|
if (oldViewProps.size != newViewProps.size) {
|
|
_activityIndicatorView.activityIndicatorViewStyle = convertActivityIndicatorViewStyle(newViewProps.size);
|
|
}
|
|
|
|
[super updateProps:props oldProps:oldProps];
|
|
}
|
|
|
|
@end
|