mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Samuel Susla
8d6b41e9bc
Summary: Changelog: [Internal] Add `Text.onTextLayout` implementation Reviewed By: JoshuaGross Differential Revision: D22865139 fbshipit-source-id: 563084754ebdc9fb23463a306c526b97c61f85ec
78 lines
2.6 KiB
Plaintext
78 lines
2.6 KiB
Plaintext
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#include "TextLayoutManager.h"
|
|
#include <react/utils/ManagedObjectWrapper.h>
|
|
|
|
#import "RCTTextLayoutManager.h"
|
|
|
|
namespace facebook {
|
|
namespace react {
|
|
|
|
TextLayoutManager::TextLayoutManager(ContextContainer::Shared const &contextContainer)
|
|
{
|
|
self_ = wrapManagedObject([RCTTextLayoutManager new]);
|
|
}
|
|
|
|
std::shared_ptr<void> TextLayoutManager::getNativeTextLayoutManager() const
|
|
{
|
|
assert(self_ && "Stored NativeTextLayoutManager must not be null.");
|
|
return self_;
|
|
}
|
|
|
|
TextMeasurement TextLayoutManager::measure(
|
|
AttributedStringBox attributedStringBox,
|
|
ParagraphAttributes paragraphAttributes,
|
|
LayoutConstraints layoutConstraints) const
|
|
{
|
|
RCTTextLayoutManager *textLayoutManager = (RCTTextLayoutManager *)unwrapManagedObject(self_);
|
|
|
|
auto measurement = TextMeasurement{};
|
|
|
|
switch (attributedStringBox.getMode()) {
|
|
case AttributedStringBox::Mode::Value: {
|
|
auto &attributedString = attributedStringBox.getValue();
|
|
|
|
measurement = measureCache_.get(
|
|
{attributedString, paragraphAttributes, layoutConstraints}, [&](TextMeasureCacheKey const &key) {
|
|
return [textLayoutManager measureAttributedString:attributedString
|
|
paragraphAttributes:paragraphAttributes
|
|
layoutConstraints:layoutConstraints];
|
|
});
|
|
break;
|
|
}
|
|
|
|
case AttributedStringBox::Mode::OpaquePointer: {
|
|
NSAttributedString *nsAttributedString =
|
|
(NSAttributedString *)unwrapManagedObject(attributedStringBox.getOpaquePointer());
|
|
|
|
measurement = [textLayoutManager measureNSAttributedString:nsAttributedString
|
|
paragraphAttributes:paragraphAttributes
|
|
layoutConstraints:layoutConstraints];
|
|
break;
|
|
}
|
|
}
|
|
|
|
measurement.size = layoutConstraints.clamp(measurement.size);
|
|
|
|
return measurement;
|
|
}
|
|
|
|
LinesMeasurements TextLayoutManager::measureLines(
|
|
AttributedString attributedString,
|
|
ParagraphAttributes paragraphAttributes,
|
|
Size size) const
|
|
{
|
|
RCTTextLayoutManager *textLayoutManager = (RCTTextLayoutManager *)unwrapManagedObject(self_);
|
|
return [textLayoutManager getLinesForAttributedString:attributedString
|
|
paragraphAttributes:paragraphAttributes
|
|
size:{size.width, size.height}];
|
|
}
|
|
|
|
} // namespace react
|
|
} // namespace facebook
|