mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
empyrical
224c85a0ba
Summary: Original PR contents: This pull request updates the Podspecs and associated build scripts, and some source files so they build on OSS. RNTester now compiles with `fabric_enabled` again. The following changes have been made: * Various spots that were pointing to the old `ReactCommon/fabric` location have now been updated to `ReactCommon/react/renderer` * Files that were attempting to use internal FB header `FBRCTFabricComponentsPlugins.h` were changed to use `RCTFabricComponentsPlugins.h` * `RCTFabricComponentsPlugins` in OSS was updated to include the `Image` fabric component (thanks tsapeta) * Replaced old `generate-rncore.sh` build script with new `generate-rncore.js` script which does not require `flow-node` and uses the `react-native-codegen` API directly, so there is no longer any need for an interim `schema-rncore.json` file. * Updated Yoga podspec which wasn't fully synced with changes from the main Yoga repo * Updated Fabric podspec with additional needed subspecs Additions to PR by hramos: * Replaced use of generate-rncore scripts with the original generate-native-modules-specs.sh script, which is now generate-specs.sh and supports both codegen for Native Modules and Components now (TurboModules/Fabric). * Codegen now runs at build time as part of the Xcode build pipeline instead of as part of `pod install`. The build script is injected by the FBReactNativeSpec pod, as the pod is part of both Fabric and non-Fabric builds. [General] [Fixed] - RNTester compiles with `fabric_enabled` again Pull Request resolved: https://github.com/facebook/react-native/pull/29810 Test Plan: RNTester now compiles and runs in the simulator again when `fabric_enabled` is set to `true`. ``` cd xplat/js/react-native-github/packages/rn-tester USE_FABRIC=1 pod install open RNTesterPods.xcworkspace ``` Reviewed By: fkgozali Differential Revision: D24058507 Pulled By: hramos fbshipit-source-id: 8b2ea3694e6cb9aa23f83f087e2995fd4320e2bb
97 lines
2.5 KiB
Plaintext
97 lines
2.5 KiB
Plaintext
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTSafeAreaViewComponentView.h"
|
|
|
|
#import <React/RCTUtils.h>
|
|
#import <react/renderer/components/safeareaview/SafeAreaViewComponentDescriptor.h>
|
|
#import <react/renderer/components/safeareaview/SafeAreaViewState.h>
|
|
#import "RCTConversions.h"
|
|
#import "RCTFabricComponentsPlugins.h"
|
|
|
|
using namespace facebook::react;
|
|
|
|
@implementation RCTSafeAreaViewComponentView {
|
|
SafeAreaViewShadowNode::ConcreteStateTeller _stateTeller;
|
|
EdgeInsets _lastPaddingStateWasUpdatedWith;
|
|
}
|
|
|
|
- (instancetype)initWithFrame:(CGRect)frame
|
|
{
|
|
if (self = [super initWithFrame:frame]) {
|
|
static auto const defaultProps = std::make_shared<SafeAreaViewProps const>();
|
|
_props = defaultProps;
|
|
self.clipsToBounds = YES;
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
- (UIEdgeInsets)_safeAreaInsets
|
|
{
|
|
if (@available(iOS 11.0, *)) {
|
|
return self.safeAreaInsets;
|
|
}
|
|
|
|
return UIEdgeInsetsZero;
|
|
}
|
|
|
|
- (void)safeAreaInsetsDidChange
|
|
{
|
|
[super safeAreaInsetsDidChange];
|
|
|
|
[self _updateStateIfNecessary];
|
|
}
|
|
|
|
- (void)_updateStateIfNecessary
|
|
{
|
|
UIEdgeInsets insets = [self _safeAreaInsets];
|
|
insets.left = RCTRoundPixelValue(insets.left);
|
|
insets.top = RCTRoundPixelValue(insets.top);
|
|
insets.right = RCTRoundPixelValue(insets.right);
|
|
insets.bottom = RCTRoundPixelValue(insets.bottom);
|
|
|
|
auto newPadding = RCTEdgeInsetsFromUIEdgeInsets(insets);
|
|
auto threshold = 1.0 / RCTScreenScale() + 0.01; // Size of a pixel plus some small threshold.
|
|
auto deltaPadding = newPadding - _lastPaddingStateWasUpdatedWith;
|
|
|
|
if (std::abs(deltaPadding.left) < threshold && std::abs(deltaPadding.top) < threshold &&
|
|
std::abs(deltaPadding.right) < threshold && std::abs(deltaPadding.bottom) < threshold) {
|
|
return;
|
|
}
|
|
|
|
_lastPaddingStateWasUpdatedWith = newPadding;
|
|
_stateTeller.updateState(SafeAreaViewState{newPadding});
|
|
}
|
|
|
|
#pragma mark - RCTComponentViewProtocol
|
|
|
|
- (void)updateState:(State::Shared const &)state oldState:(State::Shared const &)oldState
|
|
{
|
|
_stateTeller.setConcreteState(state);
|
|
[self _updateStateIfNecessary];
|
|
}
|
|
|
|
- (void)prepareForRecycle
|
|
{
|
|
[super prepareForRecycle];
|
|
_stateTeller.invalidate();
|
|
_lastPaddingStateWasUpdatedWith = {};
|
|
}
|
|
|
|
+ (ComponentDescriptorProvider)componentDescriptorProvider
|
|
{
|
|
return concreteComponentDescriptorProvider<SafeAreaViewComponentDescriptor>();
|
|
}
|
|
|
|
@end
|
|
|
|
Class<RCTComponentViewProtocol> RCTSafeAreaViewCls(void)
|
|
{
|
|
return RCTSafeAreaViewComponentView.class;
|
|
}
|