mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Valentin Shergin
2a80579ea1
Summary: ManagedObjectWrapper (`wrapManagedObject`) is used to pass pointers managed by Objective-C runtime object thought C++ parts of the framework. The wrapper consists of a shared pointer to an object with a custom deleter that calls `CFRelease`. Apparently, there is a caveat here: shared ptr implementation always calls a deleter even if the object points to `nullptr`. It's usually fine because in C++ calling `delete` on a nullptr is a no-op, not an error. But it's an error from the `CFRelease` perspective, which checks the pointer and crashes if it's nullptr. More info: https://stackoverflow.com/questions/1135214/why-would-cfreleasenull-crash https://stackoverflow.com/questions/50201967/why-unique-ptr-with-custom-deleter-wont-work-for-nullptr-while-shared-ptr-does Changelog: [Internal] Fabric-specific internal change. Reviewed By: sammy-SC Differential Revision: D21943011 fbshipit-source-id: 442ad5e274a146de112e6bd8f3c2d20f0225bf77
88 lines
2.8 KiB
Objective-C
88 lines
2.8 KiB
Objective-C
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#pragma once
|
|
|
|
#if defined(__OBJC__) && defined(__cplusplus)
|
|
#if TARGET_OS_MAC && TARGET_OS_IPHONE
|
|
|
|
#include <memory>
|
|
|
|
#import <Foundation/Foundation.h>
|
|
|
|
@interface RCTInternalGenericWeakWrapper : NSObject
|
|
@property (nonatomic, weak) id object;
|
|
@end
|
|
|
|
namespace facebook {
|
|
namespace react {
|
|
|
|
namespace detail {
|
|
|
|
/*
|
|
* A custom deleter used for the deallocation of Objective-C managed objects.
|
|
* To be used only by `wrapManagedObject`.
|
|
*/
|
|
static void wrappedManagedObjectDeleter(void *cfPointer) noexcept
|
|
{
|
|
// A shared pointer does call custom deleter on `nullptr`s.
|
|
// This is somewhat counter-intuitively but makes sense considering the type-erasured nature of shared pointer and an
|
|
// aliasing constructor feature. `CFRelease` crashes on null pointer though. Therefore we must check for this case
|
|
// explicitly.
|
|
if (cfPointer == NULL) {
|
|
return;
|
|
}
|
|
|
|
CFRelease(cfPointer);
|
|
}
|
|
|
|
}
|
|
|
|
/*
|
|
* `wrapManagedObject` and `unwrapManagedObject` are wrapper functions that
|
|
* convert ARC-managed objects into `std::shared_ptr<void>` and vice-versa. It's
|
|
* a very useful mechanism when we need to pass Objective-C objects through pure
|
|
* C++ code, pass blocks into C++ lambdas, and so on.
|
|
*
|
|
* The idea behind this mechanism is quite simple but tricky: When we
|
|
* instantiate a C++ shared pointer for a managed object, we practically call
|
|
* `CFRetain` for it once and then we represent this single retaining operation
|
|
* as a counter inside the shared pointer; when the counter became zero, we call
|
|
* `CFRelease` on the object. In this model, one bump of ARC-managed counter is
|
|
* represented as multiple bumps of C++ counter, so we can have multiple
|
|
* counters for the same object that form some kind of counters tree.
|
|
*/
|
|
inline std::shared_ptr<void> wrapManagedObject(id object) noexcept
|
|
{
|
|
return std::shared_ptr<void>((__bridge_retained void *)object, detail::wrappedManagedObjectDeleter);
|
|
}
|
|
|
|
inline id unwrapManagedObject(std::shared_ptr<void> const &object) noexcept
|
|
{
|
|
return (__bridge id)object.get();
|
|
}
|
|
|
|
inline std::shared_ptr<void> wrapManagedObjectWeakly(id object) noexcept
|
|
{
|
|
RCTInternalGenericWeakWrapper *weakWrapper = [RCTInternalGenericWeakWrapper new];
|
|
weakWrapper.object = object;
|
|
return wrapManagedObject(weakWrapper);
|
|
}
|
|
|
|
inline id unwrapManagedObjectWeakly(std::shared_ptr<void> const &object) noexcept
|
|
{
|
|
RCTInternalGenericWeakWrapper *weakWrapper = (RCTInternalGenericWeakWrapper *)unwrapManagedObject(object);
|
|
assert(weakWrapper && "`RCTInternalGenericWeakWrapper` instance must not be `nil`.");
|
|
return weakWrapper.object;
|
|
}
|
|
|
|
} // namespace react
|
|
} // namespace facebook
|
|
|
|
#endif
|
|
#endif
|