mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Ramanpreet Nara
03bd7d799e
Summary:
## Summary
Please check out D21035209.
## Changes
- Codemod all ObjC NativeModule `getTurboModuleWithJsInvoker:nativeInvoker:perfLogger` methods to `getTurboModule:(const ObjCTurboModule::Args)`
## Script
```
var withSpaces = (...args) => args.join('\s*')
var regexString = withSpaces(
'-',
'\(',
'std::shared_ptr',
'<',
'(?<turboModuleClass>(facebook::react::|react::|::|)TurboModule)',
'>',
'\)',
'getTurboModuleWithJsInvoker',
':',
'\(',
'std::shared_ptr',
'<',
'(?<fbNamespace>(facebook::react::|react::|::|))CallInvoker',
'>',
'\)',
'(?<jsInvokerInstance>[A-Za-z0-9]+)',
'nativeInvoker',
':',
'\(',
'std::shared_ptr',
'<',
'(facebook::react::|react::|::|)CallInvoker',
'>',
'\)',
'(?<nativeInvokerInstance>[A-Za-z0-9]+)',
'perfLogger',
':',
'\(',
'id',
'<',
'RCTTurboModulePerformanceLogger',
'>',
'\)',
'(?<perfLoggerInstance>[A-Za-z0-9]+)',
'{',
'return',
'std::make_shared',
'<',
'(?<specName>(facebook::react::|react::|::|)Native[%A-Za-z0-9]+SpecJSI)',
'>',
'\(',
'self',
',',
'\k<jsInvokerInstance>',
',',
'\k<nativeInvokerInstance>',
',',
'\k<perfLoggerInstance>',
'\)',
';',
'}',
)
var replaceString = `- (std::shared_ptr<$<turboModuleClass>>) getTurboModule:(const $<fbNamespace>ObjCTurboModule::InitParams &)params
{
return std::make_shared<$<specName>>(params);
}`
const exec = require('../lib/exec');
const abspath = require('../lib/abspath');
const relpath = require('../lib/relpath');
const readFile = (filename) => require('fs').readFileSync(filename, 'utf8');
const writeFile = (filename, content) => require('fs').writeFileSync(filename, content);
function main() {
const tmFiles = exec('cd ~/fbsource && xbgs -n 10000 -l getTurboModuleWithJsInvoker:').split('\n').filter(Boolean);
tmFiles
.filter((filename) => !filename.includes('microsoft-fork-of-react-native'))
.map(abspath)
.forEach((filename) => {
const source = readFile(filename);
const newSource = source.replace(new RegExp(regexString, 'g'), replaceString);
if (source == newSource) {
console.log(relpath(filename));
}
writeFile(filename, newSource);
});
}
if (!module.parent) {
main();
}
```
## Re-generating diff
```
> hg revert -r .^ --all
> node index.js # run script
```
Changelog: [iOS][Changed] - Make all ObjC NativeModules create TurboModules using ObjCTurboModule::Args
Reviewed By: PeteTheHeat
Differential Revision: D21036265
fbshipit-source-id: 404bcc548d1775ef23d793527606d02fe384a0a2
141 lines
4.5 KiB
Plaintext
141 lines
4.5 KiB
Plaintext
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTKeyboardObserver.h"
|
|
|
|
#import <FBReactNativeSpec/FBReactNativeSpec.h>
|
|
#import <React/RCTEventDispatcher.h>
|
|
|
|
#import "CoreModulesPlugins.h"
|
|
|
|
static NSDictionary *RCTParseKeyboardNotification(NSNotification *notification);
|
|
|
|
@interface RCTKeyboardObserver () <NativeKeyboardObserverSpec>
|
|
@end
|
|
|
|
@implementation RCTKeyboardObserver
|
|
|
|
RCT_EXPORT_MODULE()
|
|
|
|
- (void)startObserving
|
|
{
|
|
#if !TARGET_OS_TV
|
|
|
|
NSNotificationCenter *nc = [NSNotificationCenter defaultCenter];
|
|
|
|
#define ADD_KEYBOARD_HANDLER(NAME, SELECTOR) [nc addObserver:self selector:@selector(SELECTOR:) name:NAME object:nil]
|
|
|
|
ADD_KEYBOARD_HANDLER(UIKeyboardWillShowNotification, keyboardWillShow);
|
|
ADD_KEYBOARD_HANDLER(UIKeyboardDidShowNotification, keyboardDidShow);
|
|
ADD_KEYBOARD_HANDLER(UIKeyboardWillHideNotification, keyboardWillHide);
|
|
ADD_KEYBOARD_HANDLER(UIKeyboardDidHideNotification, keyboardDidHide);
|
|
ADD_KEYBOARD_HANDLER(UIKeyboardWillChangeFrameNotification, keyboardWillChangeFrame);
|
|
ADD_KEYBOARD_HANDLER(UIKeyboardDidChangeFrameNotification, keyboardDidChangeFrame);
|
|
|
|
#undef ADD_KEYBOARD_HANDLER
|
|
|
|
#endif
|
|
}
|
|
|
|
- (NSArray<NSString *> *)supportedEvents
|
|
{
|
|
return @[
|
|
@"keyboardWillShow",
|
|
@"keyboardDidShow",
|
|
@"keyboardWillHide",
|
|
@"keyboardDidHide",
|
|
@"keyboardWillChangeFrame",
|
|
@"keyboardDidChangeFrame"
|
|
];
|
|
}
|
|
|
|
- (void)stopObserving
|
|
{
|
|
[[NSNotificationCenter defaultCenter] removeObserver:self];
|
|
}
|
|
|
|
// Bridge might be already invalidated by the time the keyboard is about to be dismissed.
|
|
// This might happen, for example, when reload from the packager is performed.
|
|
// Thus we need to check against nil here.
|
|
#define IMPLEMENT_KEYBOARD_HANDLER(EVENT) \
|
|
-(void)EVENT : (NSNotification *)notification \
|
|
{ \
|
|
if (!self.bridge) { \
|
|
return; \
|
|
} \
|
|
[self sendEventWithName:@ #EVENT body:RCTParseKeyboardNotification(notification)]; \
|
|
}
|
|
|
|
IMPLEMENT_KEYBOARD_HANDLER(keyboardWillShow)
|
|
IMPLEMENT_KEYBOARD_HANDLER(keyboardDidShow)
|
|
IMPLEMENT_KEYBOARD_HANDLER(keyboardWillHide)
|
|
IMPLEMENT_KEYBOARD_HANDLER(keyboardDidHide)
|
|
IMPLEMENT_KEYBOARD_HANDLER(keyboardWillChangeFrame)
|
|
IMPLEMENT_KEYBOARD_HANDLER(keyboardDidChangeFrame)
|
|
|
|
- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:
|
|
(const facebook::react::ObjCTurboModule::InitParams &)params
|
|
{
|
|
return std::make_shared<facebook::react::NativeKeyboardObserverSpecJSI>(params);
|
|
}
|
|
|
|
@end
|
|
|
|
NS_INLINE NSDictionary *RCTRectDictionaryValue(CGRect rect)
|
|
{
|
|
return @{
|
|
@"screenX" : @(rect.origin.x),
|
|
@"screenY" : @(rect.origin.y),
|
|
@"width" : @(rect.size.width),
|
|
@"height" : @(rect.size.height),
|
|
};
|
|
}
|
|
|
|
static NSString *RCTAnimationNameForCurve(UIViewAnimationCurve curve)
|
|
{
|
|
switch (curve) {
|
|
case UIViewAnimationCurveEaseIn:
|
|
return @"easeIn";
|
|
case UIViewAnimationCurveEaseInOut:
|
|
return @"easeInEaseOut";
|
|
case UIViewAnimationCurveEaseOut:
|
|
return @"easeOut";
|
|
case UIViewAnimationCurveLinear:
|
|
return @"linear";
|
|
default:
|
|
return @"keyboard";
|
|
}
|
|
}
|
|
|
|
static NSDictionary *RCTParseKeyboardNotification(NSNotification *notification)
|
|
{
|
|
#if TARGET_OS_TV
|
|
return @{};
|
|
#else
|
|
NSDictionary *userInfo = notification.userInfo;
|
|
CGRect beginFrame = [userInfo[UIKeyboardFrameBeginUserInfoKey] CGRectValue];
|
|
CGRect endFrame = [userInfo[UIKeyboardFrameEndUserInfoKey] CGRectValue];
|
|
NSTimeInterval duration = [userInfo[UIKeyboardAnimationDurationUserInfoKey] doubleValue];
|
|
UIViewAnimationCurve curve =
|
|
static_cast<UIViewAnimationCurve>([userInfo[UIKeyboardAnimationCurveUserInfoKey] integerValue]);
|
|
NSInteger isLocalUserInfoKey = [userInfo[UIKeyboardIsLocalUserInfoKey] integerValue];
|
|
|
|
return @{
|
|
@"startCoordinates" : RCTRectDictionaryValue(beginFrame),
|
|
@"endCoordinates" : RCTRectDictionaryValue(endFrame),
|
|
@"duration" : @(duration * 1000.0), // ms
|
|
@"easing" : RCTAnimationNameForCurve(curve),
|
|
@"isEventFromThisApp" : isLocalUserInfoKey == 1 ? @YES : @NO,
|
|
};
|
|
#endif
|
|
}
|
|
|
|
Class RCTKeyboardObserverCls(void)
|
|
{
|
|
return RCTKeyboardObserver.class;
|
|
}
|