mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Ramanpreet Nara
03bd7d799e
Summary:
## Summary
Please check out D21035209.
## Changes
- Codemod all ObjC NativeModule `getTurboModuleWithJsInvoker:nativeInvoker:perfLogger` methods to `getTurboModule:(const ObjCTurboModule::Args)`
## Script
```
var withSpaces = (...args) => args.join('\s*')
var regexString = withSpaces(
'-',
'\(',
'std::shared_ptr',
'<',
'(?<turboModuleClass>(facebook::react::|react::|::|)TurboModule)',
'>',
'\)',
'getTurboModuleWithJsInvoker',
':',
'\(',
'std::shared_ptr',
'<',
'(?<fbNamespace>(facebook::react::|react::|::|))CallInvoker',
'>',
'\)',
'(?<jsInvokerInstance>[A-Za-z0-9]+)',
'nativeInvoker',
':',
'\(',
'std::shared_ptr',
'<',
'(facebook::react::|react::|::|)CallInvoker',
'>',
'\)',
'(?<nativeInvokerInstance>[A-Za-z0-9]+)',
'perfLogger',
':',
'\(',
'id',
'<',
'RCTTurboModulePerformanceLogger',
'>',
'\)',
'(?<perfLoggerInstance>[A-Za-z0-9]+)',
'{',
'return',
'std::make_shared',
'<',
'(?<specName>(facebook::react::|react::|::|)Native[%A-Za-z0-9]+SpecJSI)',
'>',
'\(',
'self',
',',
'\k<jsInvokerInstance>',
',',
'\k<nativeInvokerInstance>',
',',
'\k<perfLoggerInstance>',
'\)',
';',
'}',
)
var replaceString = `- (std::shared_ptr<$<turboModuleClass>>) getTurboModule:(const $<fbNamespace>ObjCTurboModule::InitParams &)params
{
return std::make_shared<$<specName>>(params);
}`
const exec = require('../lib/exec');
const abspath = require('../lib/abspath');
const relpath = require('../lib/relpath');
const readFile = (filename) => require('fs').readFileSync(filename, 'utf8');
const writeFile = (filename, content) => require('fs').writeFileSync(filename, content);
function main() {
const tmFiles = exec('cd ~/fbsource && xbgs -n 10000 -l getTurboModuleWithJsInvoker:').split('\n').filter(Boolean);
tmFiles
.filter((filename) => !filename.includes('microsoft-fork-of-react-native'))
.map(abspath)
.forEach((filename) => {
const source = readFile(filename);
const newSource = source.replace(new RegExp(regexString, 'g'), replaceString);
if (source == newSource) {
console.log(relpath(filename));
}
writeFile(filename, newSource);
});
}
if (!module.parent) {
main();
}
```
## Re-generating diff
```
> hg revert -r .^ --all
> node index.js # run script
```
Changelog: [iOS][Changed] - Make all ObjC NativeModules create TurboModules using ObjCTurboModule::Args
Reviewed By: PeteTheHeat
Differential Revision: D21036265
fbshipit-source-id: 404bcc548d1775ef23d793527606d02fe384a0a2
105 lines
3.6 KiB
Plaintext
105 lines
3.6 KiB
Plaintext
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import <React/RCTImageEditingManager.h>
|
|
|
|
#import <FBReactNativeSpec/FBReactNativeSpec.h>
|
|
#import <React/RCTConvert.h>
|
|
#import <React/RCTImageLoader.h>
|
|
#import <React/RCTImageStoreManager.h>
|
|
#import <React/RCTImageUtils.h>
|
|
#import <React/RCTImageLoaderProtocol.h>
|
|
#import <React/RCTLog.h>
|
|
#import <React/RCTUtils.h>
|
|
#import <UIKit/UIKit.h>
|
|
|
|
#import "RCTImagePlugins.h"
|
|
|
|
@interface RCTImageEditingManager() <NativeImageEditorSpec>
|
|
@end
|
|
|
|
@implementation RCTImageEditingManager
|
|
|
|
RCT_EXPORT_MODULE()
|
|
|
|
@synthesize bridge = _bridge;
|
|
|
|
/**
|
|
* Crops an image and adds the result to the image store.
|
|
*
|
|
* @param imageRequest An image URL
|
|
* @param cropData Dictionary with `offset`, `size` and `displaySize`.
|
|
* `offset` and `size` are relative to the full-resolution image size.
|
|
* `displaySize` is an optimization - if specified, the image will
|
|
* be scaled down to `displaySize` rather than `size`.
|
|
* All units are in px (not points).
|
|
*/
|
|
RCT_EXPORT_METHOD(cropImage:(NSURLRequest *)imageRequest
|
|
cropData:(JS::NativeImageEditor::Options &)cropData
|
|
successCallback:(RCTResponseSenderBlock)successCallback
|
|
errorCallback:(RCTResponseSenderBlock)errorCallback)
|
|
{
|
|
CGRect rect = {
|
|
[RCTConvert CGPoint:@{
|
|
@"x": @(cropData.offset().x()),
|
|
@"y": @(cropData.offset().y()),
|
|
}],
|
|
[RCTConvert CGSize:@{
|
|
@"width": @(cropData.size().width()),
|
|
@"height": @(cropData.size().height()),
|
|
}]
|
|
};
|
|
|
|
// We must keep a copy of cropData so that we can access data from it at a later time
|
|
JS::NativeImageEditor::Options cropDataCopy = cropData;
|
|
|
|
[[_bridge moduleForName:@"ImageLoader" lazilyLoadIfNecessary:YES]
|
|
loadImageWithURLRequest:imageRequest callback:^(NSError *error, UIImage *image) {
|
|
if (error) {
|
|
errorCallback(@[RCTJSErrorFromNSError(error)]);
|
|
return;
|
|
}
|
|
|
|
// Crop image
|
|
CGSize targetSize = rect.size;
|
|
CGRect targetRect = {{-rect.origin.x, -rect.origin.y}, image.size};
|
|
CGAffineTransform transform = RCTTransformFromTargetRect(image.size, targetRect);
|
|
UIImage *croppedImage = RCTTransformImage(image, targetSize, image.scale, transform);
|
|
|
|
// Scale image
|
|
if (cropDataCopy.displaySize()) {
|
|
targetSize = [RCTConvert CGSize:@{@"width": @(cropDataCopy.displaySize()->width()), @"height": @(cropDataCopy.displaySize()->height())}]; // in pixels
|
|
RCTResizeMode resizeMode = [RCTConvert RCTResizeMode:cropDataCopy.resizeMode() ?: @"contain"];
|
|
targetRect = RCTTargetRect(croppedImage.size, targetSize, 1, resizeMode);
|
|
transform = RCTTransformFromTargetRect(croppedImage.size, targetRect);
|
|
croppedImage = RCTTransformImage(croppedImage, targetSize, image.scale, transform);
|
|
}
|
|
|
|
// Store image
|
|
[self->_bridge.imageStoreManager storeImage:croppedImage withBlock:^(NSString *croppedImageTag) {
|
|
if (!croppedImageTag) {
|
|
NSString *errorMessage = @"Error storing cropped image in RCTImageStoreManager";
|
|
RCTLogWarn(@"%@", errorMessage);
|
|
errorCallback(@[RCTJSErrorFromNSError(RCTErrorWithMessage(errorMessage))]);
|
|
return;
|
|
}
|
|
successCallback(@[croppedImageTag]);
|
|
}];
|
|
}];
|
|
}
|
|
|
|
- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:(const facebook::react::ObjCTurboModule::InitParams &)params
|
|
{
|
|
return std::make_shared<facebook::react::NativeImageEditorSpecJSI>(params);
|
|
}
|
|
|
|
@end
|
|
|
|
Class RCTImageEditingManagerCls() {
|
|
return RCTImageEditingManager.class;
|
|
}
|