mirror of
https://github.com/facebook/react-native.git
synced 2026-11-18 20:19:07 +00:00
Summary: Pull Request resolved: https://github.com/facebook/react-native/pull/36335 This change depends on [this PR](https://github.com/react-native-community/cli/pull/1849) of the CLI that introduces the `unstable_reactLegacyComponent` field in the `react-native.config.js` file. This change introduce a JS script that reads that fields and generated a method in an object to return a list of components to be registered. The `RCTAppDelegate` has been updated to read those components and to automatically register them into the interop layer. Notice that a user can just update the `react-native.config.js` and rebuild the app to integrate these changes, there is no need to reinstall the pods. The idea behind this logic is to let the user know which components they are using with the interop layer, rather than rely on some black magic that could leave them blind to the need of actually migrate their apps. ## Changelog: [iOS][Changed] - Implement mechanism to register legacy components in the iOS Fabric interop layer Reviewed By: cortinico, dmytrorykun Differential Revision: D43665973 fbshipit-source-id: b4e8d71fa1bbed7a6130ee4f83a6221394d5306e
192 lines
6.1 KiB
Plaintext
192 lines
6.1 KiB
Plaintext
/*
|
|
* Copyright (c) Meta Platforms, Inc. and affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTAppDelegate.h"
|
|
#import <React/RCTRootView.h>
|
|
#import "RCTAppSetupUtils.h"
|
|
|
|
#if RCT_NEW_ARCH_ENABLED
|
|
#import <React/CoreModulesPlugins.h>
|
|
#import <React/RCTCxxBridgeDelegate.h>
|
|
#import <React/RCTFabricSurfaceHostingProxyRootView.h>
|
|
#import <React/RCTLegacyViewManagerInteropComponentView.h>
|
|
#import <React/RCTSurfacePresenter.h>
|
|
#import <React/RCTSurfacePresenterBridgeAdapter.h>
|
|
#import <ReactCommon/RCTTurboModuleManager.h>
|
|
#import <react/config/ReactNativeConfig.h>
|
|
#import <react/renderer/runtimescheduler/RuntimeScheduler.h>
|
|
#import <react/renderer/runtimescheduler/RuntimeSchedulerCallInvoker.h>
|
|
#import "RCTLegacyInteropComponents.h"
|
|
|
|
static NSString *const kRNConcurrentRoot = @"concurrentRoot";
|
|
|
|
@interface RCTAppDelegate () <RCTTurboModuleManagerDelegate, RCTCxxBridgeDelegate> {
|
|
std::shared_ptr<const facebook::react::ReactNativeConfig> _reactNativeConfig;
|
|
facebook::react::ContextContainer::Shared _contextContainer;
|
|
std::shared_ptr<facebook::react::RuntimeScheduler> _runtimeScheduler;
|
|
}
|
|
@end
|
|
|
|
#endif
|
|
|
|
@implementation RCTAppDelegate
|
|
|
|
#if RCT_NEW_ARCH_ENABLED
|
|
- (instancetype)init
|
|
{
|
|
if (self = [super init]) {
|
|
_contextContainer = std::make_shared<facebook::react::ContextContainer const>();
|
|
_reactNativeConfig = std::make_shared<facebook::react::EmptyReactNativeConfig const>();
|
|
_contextContainer->insert("ReactNativeConfig", _reactNativeConfig);
|
|
}
|
|
return self;
|
|
}
|
|
#endif
|
|
|
|
- (BOOL)application:(UIApplication *)application didFinishLaunchingWithOptions:(NSDictionary *)launchOptions
|
|
{
|
|
BOOL enableTM = NO;
|
|
#if RCT_NEW_ARCH_ENABLED
|
|
enableTM = self.turboModuleEnabled;
|
|
#endif
|
|
RCTAppSetupPrepareApp(application, enableTM);
|
|
|
|
if (!self.bridge) {
|
|
self.bridge = [self createBridgeWithDelegate:self launchOptions:launchOptions];
|
|
}
|
|
#if RCT_NEW_ARCH_ENABLED
|
|
self.bridgeAdapter = [[RCTSurfacePresenterBridgeAdapter alloc] initWithBridge:self.bridge
|
|
contextContainer:_contextContainer];
|
|
self.bridge.surfacePresenter = self.bridgeAdapter.surfacePresenter;
|
|
|
|
[self unstable_registerLegacyComponents];
|
|
#endif
|
|
|
|
NSDictionary *initProps = [self prepareInitialProps];
|
|
UIView *rootView = [self createRootViewWithBridge:self.bridge moduleName:self.moduleName initProps:initProps];
|
|
|
|
self.window = [[UIWindow alloc] initWithFrame:[UIScreen mainScreen].bounds];
|
|
UIViewController *rootViewController = [self createRootViewController];
|
|
rootViewController.view = rootView;
|
|
self.window.rootViewController = rootViewController;
|
|
[self.window makeKeyAndVisible];
|
|
|
|
return YES;
|
|
}
|
|
|
|
- (NSURL *)sourceURLForBridge:(RCTBridge *)bridge
|
|
{
|
|
[NSException raise:@"RCTBridgeDelegate::sourceURLForBridge not implemented"
|
|
format:@"Subclasses must implement a valid sourceURLForBridge method"];
|
|
return nil;
|
|
}
|
|
|
|
- (NSDictionary *)prepareInitialProps
|
|
{
|
|
NSMutableDictionary *initProps = self.initialProps ? [self.initialProps mutableCopy] : [NSMutableDictionary new];
|
|
|
|
#ifdef RCT_NEW_ARCH_ENABLED
|
|
// Hardcoding the Concurrent Root as it it not recommended to
|
|
// have the concurrentRoot turned off when Fabric is enabled.
|
|
initProps[kRNConcurrentRoot] = @([self fabricEnabled]);
|
|
#endif
|
|
|
|
return initProps;
|
|
}
|
|
|
|
- (RCTBridge *)createBridgeWithDelegate:(id<RCTBridgeDelegate>)delegate launchOptions:(NSDictionary *)launchOptions
|
|
{
|
|
return [[RCTBridge alloc] initWithDelegate:delegate launchOptions:launchOptions];
|
|
}
|
|
|
|
- (UIView *)createRootViewWithBridge:(RCTBridge *)bridge
|
|
moduleName:(NSString *)moduleName
|
|
initProps:(NSDictionary *)initProps
|
|
{
|
|
BOOL enableFabric = NO;
|
|
#if RCT_NEW_ARCH_ENABLED
|
|
enableFabric = self.fabricEnabled;
|
|
#endif
|
|
UIView *rootView = RCTAppSetupDefaultRootView(bridge, moduleName, initProps, enableFabric);
|
|
if (@available(iOS 13.0, *)) {
|
|
rootView.backgroundColor = [UIColor systemBackgroundColor];
|
|
} else {
|
|
rootView.backgroundColor = [UIColor whiteColor];
|
|
}
|
|
|
|
return rootView;
|
|
}
|
|
|
|
- (UIViewController *)createRootViewController
|
|
{
|
|
return [UIViewController new];
|
|
}
|
|
|
|
#if RCT_NEW_ARCH_ENABLED
|
|
#pragma mark - RCTCxxBridgeDelegate
|
|
- (std::unique_ptr<facebook::react::JSExecutorFactory>)jsExecutorFactoryForBridge:(RCTBridge *)bridge
|
|
{
|
|
_runtimeScheduler = _runtimeScheduler =
|
|
std::make_shared<facebook::react::RuntimeScheduler>(RCTRuntimeExecutorFromBridge(bridge));
|
|
std::shared_ptr<facebook::react::CallInvoker> callInvoker =
|
|
std::make_shared<facebook::react::RuntimeSchedulerCallInvoker>(_runtimeScheduler);
|
|
self.turboModuleManager = [[RCTTurboModuleManager alloc] initWithBridge:bridge delegate:self jsInvoker:callInvoker];
|
|
_contextContainer->erase("RuntimeScheduler");
|
|
_contextContainer->insert("RuntimeScheduler", _runtimeScheduler);
|
|
return RCTAppSetupDefaultJsExecutorFactory(bridge, _turboModuleManager, _runtimeScheduler);
|
|
}
|
|
|
|
#pragma mark RCTTurboModuleManagerDelegate
|
|
|
|
- (Class)getModuleClassFromName:(const char *)name
|
|
{
|
|
return RCTCoreModulesClassProvider(name);
|
|
}
|
|
|
|
- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:(const std::string &)name
|
|
jsInvoker:(std::shared_ptr<facebook::react::CallInvoker>)jsInvoker
|
|
{
|
|
return nullptr;
|
|
}
|
|
|
|
- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:(const std::string &)name
|
|
initParams:
|
|
(const facebook::react::ObjCTurboModule::InitParams &)params
|
|
{
|
|
return nullptr;
|
|
}
|
|
|
|
- (id<RCTTurboModule>)getModuleInstanceFromClass:(Class)moduleClass
|
|
{
|
|
return RCTAppSetupDefaultModuleFromClass(moduleClass);
|
|
}
|
|
|
|
#pragma mark - New Arch Enabled settings
|
|
|
|
- (BOOL)turboModuleEnabled
|
|
{
|
|
return YES;
|
|
}
|
|
|
|
- (BOOL)fabricEnabled
|
|
{
|
|
return YES;
|
|
}
|
|
|
|
#pragma mark - New Arch Utilities
|
|
|
|
- (void)unstable_registerLegacyComponents
|
|
{
|
|
for (NSString *legacyComponent in [RCTLegacyInteropComponents legacyInteropComponents]) {
|
|
[RCTLegacyViewManagerInteropComponentView supportLegacyViewManagerWithName:legacyComponent];
|
|
}
|
|
}
|
|
|
|
#endif
|
|
|
|
@end
|