mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Ramanpreet Nara
3f38186b78
Summary: We're making the getTurboModule: method required for all classes that conform to RCTTurboModule. Many of our ObjC-only and Cxx NativeModules don't implement this method. This diff implements a getTurboModule: method on all those modules that returns nullptr. **Question:** Why is it fine to make ObjC-only NativeModules return nullptr from their getTurboModule: method? - Because they're only accessed from ObjC, and should appear as null on the JavaScript side. Longer term, these NativeModules will also go away. **Question:** Why is it fine to make Cxx NativeModules return nullptr from getTurboModule: method? - Because after D27316872, the TurboModuleManager checks if the module is a CxxModule first. If it is, we do an early return, and never call the module's getTurboModule: method. Changelog: [Internal] Reviewed By: JoshuaGross Differential Revision: D27316871 fbshipit-source-id: bc693f2927ab3b0de24e6e9e7699390ec0f7d729
90 lines
2.3 KiB
Plaintext
90 lines
2.3 KiB
Plaintext
/*
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import <React/RCTDataRequestHandler.h>
|
|
#import <ReactCommon/RCTTurboModule.h>
|
|
|
|
#import "RCTNetworkPlugins.h"
|
|
|
|
@interface RCTDataRequestHandler() <RCTTurboModule>
|
|
@end
|
|
|
|
@implementation RCTDataRequestHandler
|
|
{
|
|
NSOperationQueue *_queue;
|
|
}
|
|
|
|
RCT_EXPORT_MODULE()
|
|
|
|
- (void)invalidate
|
|
{
|
|
[_queue cancelAllOperations];
|
|
_queue = nil;
|
|
}
|
|
|
|
- (BOOL)canHandleRequest:(NSURLRequest *)request
|
|
{
|
|
return [request.URL.scheme caseInsensitiveCompare:@"data"] == NSOrderedSame;
|
|
}
|
|
|
|
- (NSOperation *)sendRequest:(NSURLRequest *)request
|
|
withDelegate:(id<RCTURLRequestDelegate>)delegate
|
|
{
|
|
// Lazy setup
|
|
if (!_queue) {
|
|
_queue = [NSOperationQueue new];
|
|
_queue.maxConcurrentOperationCount = 2;
|
|
}
|
|
|
|
__weak __block NSBlockOperation *weakOp;
|
|
__block NSBlockOperation *op = [NSBlockOperation blockOperationWithBlock:^{
|
|
|
|
// Get mime type
|
|
NSRange firstSemicolon = [request.URL.resourceSpecifier rangeOfString:@";"];
|
|
NSString *mimeType = firstSemicolon.length ? [request.URL.resourceSpecifier substringToIndex:firstSemicolon.location] : nil;
|
|
|
|
// Send response
|
|
NSURLResponse *response = [[NSURLResponse alloc] initWithURL:request.URL
|
|
MIMEType:mimeType
|
|
expectedContentLength:-1
|
|
textEncodingName:nil];
|
|
|
|
[delegate URLRequest:weakOp didReceiveResponse:response];
|
|
|
|
// Load data
|
|
NSError *error;
|
|
NSData *data = [NSData dataWithContentsOfURL:request.URL
|
|
options:NSDataReadingMappedIfSafe
|
|
error:&error];
|
|
if (data) {
|
|
[delegate URLRequest:weakOp didReceiveData:data];
|
|
}
|
|
[delegate URLRequest:weakOp didCompleteWithError:error];
|
|
}];
|
|
|
|
weakOp = op;
|
|
[_queue addOperation:op];
|
|
return op;
|
|
}
|
|
|
|
- (void)cancelRequest:(NSOperation *)op
|
|
{
|
|
[op cancel];
|
|
}
|
|
|
|
- (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:
|
|
(const facebook::react::ObjCTurboModule::InitParams &)params
|
|
{
|
|
return nullptr;
|
|
}
|
|
|
|
@end
|
|
|
|
Class RCTDataRequestHandlerCls(void) {
|
|
return RCTDataRequestHandler.class;
|
|
}
|