mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Nicola CortiandFacebook GitHub Bot
f11608da4e
Summary: Pull Request resolved: https://github.com/facebook/react-native/pull/41832 I'm removing the `installArchives` task and all the setup to publish the Maven Local inside the NPM package as we're not using this entirely and we won't be able to use it anyway (as the Maven Local is too big to fit an NPM package). Changelog: [Internal] [Changed] - Remove the installArchives task Reviewed By: GijsWeterings Differential Revision: D51890224 fbshipit-source-id: 3ffdc67a9fe931118596f6f74a5a2df0313ca3f2
83 lines
2.6 KiB
Groovy
83 lines
2.6 KiB
Groovy
/*
|
|
* Copyright (c) Meta Platforms, Inc. and affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
apply plugin: 'maven-publish'
|
|
apply plugin: 'signing'
|
|
|
|
def isSnapshot = findProperty("isSnapshot")?.toBoolean()
|
|
def signingKey = findProperty("SIGNING_KEY")
|
|
def signingPwd = findProperty("SIGNING_PWD")
|
|
|
|
def reactAndroidProjectDir = project(':packages:react-native:ReactAndroid').projectDir
|
|
def mavenTempLocalUrl = "file:///tmp/maven-local"
|
|
|
|
publishing {
|
|
publications {
|
|
release(MavenPublication) {
|
|
afterEvaluate {
|
|
// We do a multi variant release, so for Android libraries
|
|
// we publish `components.release`
|
|
if (plugins.hasPlugin("com.android.library")) {
|
|
from components.default
|
|
}
|
|
}
|
|
|
|
// We populate the publishing version using the project version,
|
|
// appending -SNAPSHOT if on nightly or prerelase.
|
|
if (isSnapshot) {
|
|
version = this.version + "-SNAPSHOT"
|
|
} else {
|
|
version = this.version
|
|
}
|
|
|
|
pom {
|
|
name = "react-native"
|
|
description = "A framework for building native apps with React"
|
|
url = "https://github.com/facebook/react-native"
|
|
|
|
developers {
|
|
developer {
|
|
id = "facebook"
|
|
name = "Facebook"
|
|
}
|
|
}
|
|
|
|
licenses {
|
|
license {
|
|
name = "MIT License"
|
|
url = "https://github.com/facebook/react-native/blob/HEAD/LICENSE"
|
|
distribution = "repo"
|
|
}
|
|
}
|
|
|
|
scm {
|
|
url = "https://github.com/facebook/react-native.git"
|
|
connection = "scm:git:https://github.com/facebook/react-native.git"
|
|
developerConnection = "scm:git:git@github.com:facebook/react-native.git"
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
repositories {
|
|
maven {
|
|
name = "mavenTempLocal"
|
|
url = mavenTempLocalUrl
|
|
}
|
|
}
|
|
|
|
if (signingKey && signingPwd) {
|
|
logger.info("PGP Key found - Signing enabled")
|
|
signing {
|
|
useInMemoryPgpKeys(signingKey, signingPwd)
|
|
sign(publishing.publications.release)
|
|
}
|
|
} else {
|
|
logger.info("Signing disabled as the PGP key was not found")
|
|
}
|
|
}
|