mirror of
https://github.com/facebook/react-native.git
synced 2025-11-01 09:14:26 +00:00
Oskar Kwaśniewski
258d8e51b4
Summary: This PR introduces the `vision` interfaceIdiom to check if the app runs on visionOS. An update to the documentation should follow this change. ## Changelog: [IOS] [ADDED] - Introduce `vision` interfaceIdiom Pull Request resolved: https://github.com/facebook/react-native/pull/42243 Test Plan: This change has been used in `react-native-visionos` and the interfaceIdiom changes **only** when running in the non-compatibility mode. But it's still useful to have this upstream if at some point React native would compile to visionOS natively Reviewed By: cortinico Differential Revision: D52730028 Pulled By: cipolleschi fbshipit-source-id: 711c5c2c6c7fe05b3ff8da7383b5e63e9e04acfa
104 lines
2.7 KiB
Plaintext
104 lines
2.7 KiB
Plaintext
/*
|
|
* Copyright (c) Meta Platforms, Inc. and affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTPlatform.h"
|
|
|
|
#import <UIKit/UIKit.h>
|
|
|
|
#import <FBReactNativeSpec/FBReactNativeSpec.h>
|
|
#import <React/RCTUtils.h>
|
|
#import <React/RCTVersion.h>
|
|
|
|
#import "CoreModulesPlugins.h"
|
|
|
|
#import <optional>
|
|
|
|
using namespace facebook::react;
|
|
|
|
static NSString *interfaceIdiom(UIUserInterfaceIdiom idiom)
|
|
{
|
|
switch (idiom) {
|
|
case UIUserInterfaceIdiomPhone:
|
|
return @"phone";
|
|
case UIUserInterfaceIdiomPad:
|
|
return @"pad";
|
|
case UIUserInterfaceIdiomTV:
|
|
return @"tv";
|
|
case UIUserInterfaceIdiomCarPlay:
|
|
return @"carplay";
|
|
#if TARGET_OS_VISION
|
|
case UIUserInterfaceIdiomVision:
|
|
return @"vision";
|
|
#endif
|
|
default:
|
|
return @"unknown";
|
|
}
|
|
}
|
|
|
|
@interface RCTPlatform () <NativePlatformConstantsIOSSpec>
|
|
@end
|
|
|
|
@implementation RCTPlatform
|
|
|
|
RCT_EXPORT_MODULE(PlatformConstants)
|
|
|
|
+ (BOOL)requiresMainQueueSetup
|
|
{
|
|
return YES;
|
|
}
|
|
|
|
- (dispatch_queue_t)methodQueue
|
|
{
|
|
return dispatch_get_main_queue();
|
|
}
|
|
|
|
// TODO: Use the generated struct return type.
|
|
- (ModuleConstants<JS::NativePlatformConstantsIOS::Constants>)constantsToExport
|
|
{
|
|
return (ModuleConstants<JS::NativePlatformConstantsIOS::Constants>)[self getConstants];
|
|
}
|
|
|
|
- (ModuleConstants<JS::NativePlatformConstantsIOS::Constants>)getConstants
|
|
{
|
|
__block ModuleConstants<JS::NativePlatformConstantsIOS::Constants> constants;
|
|
RCTUnsafeExecuteOnMainQueueSync(^{
|
|
UIDevice *device = [UIDevice currentDevice];
|
|
auto versions = RCTGetReactNativeVersion();
|
|
constants = typedConstants<JS::NativePlatformConstantsIOS::Constants>({
|
|
.forceTouchAvailable = RCTForceTouchAvailable() ? true : false, .osVersion = [device systemVersion],
|
|
.systemName = [device systemName], .interfaceIdiom = interfaceIdiom([device userInterfaceIdiom]),
|
|
.isTesting = RCTRunningInTestEnvironment() ? true : false,
|
|
.reactNativeVersion = JS::NativePlatformConstantsIOS::ConstantsReactNativeVersion::Builder(
|
|
{.minor = [versions[@"minor"] doubleValue],
|
|
.major = [versions[@"major"] doubleValue],
|
|
.patch = [versions[@"patch"] doubleValue],
|
|
.prerelease = [versions[@"prerelease"] isKindOfClass:[NSNull class]]
|
|
? std::optional<double>{}
|
|
: [versions[@"prerelease"] doubleValue]}),
|
|
#if TARGET_OS_MACCATALYST
|
|
.isMacCatalyst = true,
|
|
#else
|
|
.isMacCatalyst = false,
|
|
#endif
|
|
});
|
|
});
|
|
|
|
return constants;
|
|
}
|
|
|
|
- (std::shared_ptr<TurboModule>)getTurboModule:(const ObjCTurboModule::InitParams &)params
|
|
{
|
|
return std::make_shared<NativePlatformConstantsIOSSpecJSI>(params);
|
|
}
|
|
|
|
@end
|
|
|
|
Class RCTPlatformCls(void)
|
|
{
|
|
return RCTPlatform.class;
|
|
}
|