Make RCTWebSocketModule TurboModule-compatible

Summary: Changelog: [iOS][Added] - Make RCTWebSocketModule TurboModule-compatible Reviewed By: PeteTheHeat Differential Revision: D18353766 fbshipit-source-id: fde0f6593dd203ab3dcb8f9cf40012ba4761d6ba
2025-11-01 09:14:26 +00:00 · 2019-11-08 14:14:46 -08:00
parent 1b2992e8b3
commit d73ae1baa3
11 changed files with 68 additions and 60 deletions
@@ -0,0 +1,215 @@
+/*
+ * Copyright (c) Facebook, Inc. and its affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import <React/RCTWebSocketModule.h>
+
+#import <objc/runtime.h>
+
+#import <FBReactNativeSpec/FBReactNativeSpec.h>
+#import <React/RCTConvert.h>
+#import <React/RCTUtils.h>
+#import <React/RCTSRWebSocket.h>
+
+#import "CoreModulesPlugins.h"
+
+@implementation RCTSRWebSocket (React)
+
+- (NSNumber *)reactTag
+{
+  return objc_getAssociatedObject(self, _cmd);
+}
+
+- (void)setReactTag:(NSNumber *)reactTag
+{
+  objc_setAssociatedObject(self, @selector(reactTag), reactTag, OBJC_ASSOCIATION_COPY_NONATOMIC);
+}
+
+@end
+
+@interface RCTWebSocketModule () <RCTSRWebSocketDelegate, NativeWebSocketModuleSpec>
+
+@end
+
+@implementation RCTWebSocketModule
+{
+  NSMutableDictionary<NSNumber *, RCTSRWebSocket *> *_sockets;
+  NSMutableDictionary<NSNumber *, id<RCTWebSocketContentHandler>> *_contentHandlers;
+}
+
+RCT_EXPORT_MODULE()
+
+- (dispatch_queue_t)methodQueue
+{
+  return dispatch_get_main_queue();
+}
+
+- (NSArray *)supportedEvents
+{
+  return @[@"websocketMessage",
+           @"websocketOpen",
+           @"websocketFailed",
+           @"websocketClosed"];
+}
+
+- (void)invalidate
+{
+  _contentHandlers = nil;
+  for (RCTSRWebSocket *socket in _sockets.allValues) {
+    socket.delegate = nil;
+    [socket close];
+  }
+}
+
+RCT_EXPORT_METHOD(connect:(NSURL *)URL protocols:(NSArray *)protocols options:(JS::NativeWebSocketModule::SpecConnectOptions &)options socketID:(double)socketID)
+{
+  NSMutableURLRequest *request = [NSMutableURLRequest requestWithURL:URL];
+
+  // We load cookies from sharedHTTPCookieStorage (shared with XHR and
+  // fetch). To get secure cookies for wss URLs, replace wss with https
+  // in the URL.
+  NSURLComponents *components = [NSURLComponents componentsWithURL:URL resolvingAgainstBaseURL:true];
+  if ([components.scheme.lowercaseString isEqualToString:@"wss"]) {
+    components.scheme = @"https";
+  }
+
+  // Load and set the cookie header.
+  NSArray<NSHTTPCookie *> *cookies = [[NSHTTPCookieStorage sharedHTTPCookieStorage] cookiesForURL:components.URL];
+  request.allHTTPHeaderFields = [NSHTTPCookie requestHeaderFieldsWithCookies:cookies];
+
+  // Load supplied headers
+  if ([options.headers() isKindOfClass:NSDictionary.class]) {
+    NSDictionary *headers = (NSDictionary *)options.headers();
+    [headers enumerateKeysAndObjectsUsingBlock:^(NSString *key, id value, BOOL *stop) {
+      [request addValue:[RCTConvert NSString:value] forHTTPHeaderField:key];
+    }];
+  }
+
+  RCTSRWebSocket *webSocket = [[RCTSRWebSocket alloc] initWithURLRequest:request protocols:protocols];
+  [webSocket setDelegateDispatchQueue:[self methodQueue]];
+  webSocket.delegate = self;
+  webSocket.reactTag = @(socketID);
+  if (!_sockets) {
+    _sockets = [NSMutableDictionary new];
+  }
+  _sockets[@(socketID)] = webSocket;
+  [webSocket open];
+}
+
+RCT_EXPORT_METHOD(send:(NSString *)message forSocketID:(double)socketID)
+{
+  [_sockets[@(socketID)] send:message];
+}
+
+RCT_EXPORT_METHOD(sendBinary:(NSString *)base64String forSocketID:(double)socketID)
+{
+  [self sendData:[[NSData alloc] initWithBase64EncodedString:base64String options:0] forSocketID:@(socketID)];
+}
+
+- (void)sendData:(NSData *)data forSocketID:(NSNumber * __nonnull)socketID
+{
+  [_sockets[socketID] send:data];
+}
+
+RCT_EXPORT_METHOD(ping:(double)socketID)
+{
+  [_sockets[@(socketID)] sendPing:NULL];
+}
+
+RCT_EXPORT_METHOD(close:(double)code reason:(NSString *)reason socketID:(double)socketID)
+{
+  [_sockets[@(socketID)] closeWithCode:code reason:reason];
+  [_sockets removeObjectForKey:@(socketID)];
+}
+
+- (void)setContentHandler:(id<RCTWebSocketContentHandler>)handler forSocketID:(NSString *)socketID
+{
+  if (!_contentHandlers) {
+    _contentHandlers = [NSMutableDictionary new];
+  }
+  _contentHandlers[socketID] = handler;
+}
+
+#pragma mark - RCTSRWebSocketDelegate methods
+
+- (void)webSocket:(RCTSRWebSocket *)webSocket didReceiveMessage:(id)message
+{
+  NSString *type;
+
+  NSNumber *socketID = [webSocket reactTag];
+  id contentHandler = _contentHandlers[socketID];
+  if (contentHandler) {
+    message = [contentHandler processWebsocketMessage:message forSocketID:socketID withType:&type];
+  } else {
+    if ([message isKindOfClass:[NSData class]]) {
+      type = @"binary";
+      message = [message base64EncodedStringWithOptions:0];
+    } else {
+      type = @"text";
+    }
+  }
+
+  [self sendEventWithName:@"websocketMessage" body:@{
+    @"data": message,
+    @"type": type,
+    @"id": webSocket.reactTag
+  }];
+}
+
+- (void)webSocketDidOpen:(RCTSRWebSocket *)webSocket
+{
+  [self sendEventWithName:@"websocketOpen" body:@{
+    @"id": webSocket.reactTag,
+    @"protocol": webSocket.protocol ? webSocket.protocol : @""
+  }];
+}
+
+- (void)webSocket:(RCTSRWebSocket *)webSocket didFailWithError:(NSError *)error
+{
+  NSNumber *socketID = [webSocket reactTag];
+  _contentHandlers[socketID] = nil;
+  _sockets[socketID] = nil;
+  [self sendEventWithName:@"websocketFailed" body:@{
+    @"message": error.localizedDescription,
+    @"id": socketID
+  }];
+}
+
+- (void)webSocket:(RCTSRWebSocket *)webSocket
+ didCloseWithCode:(NSInteger)code
+           reason:(NSString *)reason
+         wasClean:(BOOL)wasClean
+{
+  NSNumber *socketID = [webSocket reactTag];
+  _contentHandlers[socketID] = nil;
+  _sockets[socketID] = nil;
+  [self sendEventWithName:@"websocketClosed" body:@{
+    @"code": @(code),
+    @"reason": RCTNullIfNil(reason),
+    @"clean": @(wasClean),
+    @"id": socketID
+  }];
+}
+
+- (std::shared_ptr<facebook::react::TurboModule>)getTurboModuleWithJsInvoker:(std::shared_ptr<facebook::react::CallInvoker>)jsInvoker
+{
+  return std::make_shared<facebook::react::NativeWebSocketModuleSpecJSI>(self, jsInvoker);
+}
+
+@end
+
+@implementation RCTBridge (RCTWebSocketModule)
+
+- (RCTWebSocketModule *)webSocketModule
+{
+  return [self moduleForClass:[RCTWebSocketModule class]];
+}
+
+@end
+
+Class RCTWebSocketModuleCls(void) {
+  return RCTWebSocketModule.class;
+}